(Code trong video đã được sửa đổi bằng code trong bài viết này.)

Option Explicit 
'//Author: Nguyen Duy Tuan - https://bluesofts.net OR https://atoolspro.com
'//The first: goto menu Tools -> References... check item "addinatools.dll"
Const MyCloudType = ctGoogleDrive  'If Excel Online: ctOneDrive
Const FileID = "https://docs.google.com/spreadsheets/d/1fPaexjiuLSEY3YQdVf7....HiKWSL9SaaGGvGkbU/edit?" 
Dim MyCloud As New BSCloud  '//Cloud controller
Dim TaxPer As Double 
'-----------------------------------------------
'//OpenWorkbook on drive
Function OpenCloudWorkbook() As BSCloudWorkbook 
   If MyCloud Is Nothing Then Set MyCloud = New BSCloud 
   If Not MyCloud.Connected(MyCloudType) Then 
      If Not MyCloud.OpenAuthor(Application, MyCloudType, Application.Hwnd) Then 
         MsgBoxW "Con not connect to your drive.", vbCritical, "Connect Error" 
         Exit Function 
      End If 
   End If 
   '//Connected Ok! Open Workbook
   Set OpenCloudWorkbook = MyCloud.Workbooks.Open(FileID) 
End Function 
'-----------------------------------------------
Private Sub UserForm_Initialize() 
   Dim wbSrc As BSCloudWorkbook 
   Dim wsSrc As BSCloudWorksheet 
   Set wbSrc = OpenCloudWorkbook 
   Set wsSrc = wbSrc.Sheets("items") 
   '//Load data from Google Sheets to combobox
   cbItems.ColumnCount = 3 
   cbItems.List = wsSrc.Range("A2:C" & wsSrc.LastRow).Value 
End Sub 
'-----------------------------------------------
Private Sub cbItems_Change() 
   lblItemName.Caption = cbItems.List(cbItems.ListIndex, 1) 
   TaxPer = cbItems.List(cbItems.ListIndex, 2) 
End Sub 
'-----------------------------------------------
Private Sub UpdateValues() 
   txtTax.Value = TaxPer * Val(txtIncome.Value) 
   txtTotal.Value = Val(txtIncome.Value) + Val(txtTax.Value) 
End Sub 
'-----------------------------------------------
Private Sub txtTax_Change() 
   UpdateValues 
End Sub 
'-----------------------------------------------
Private Sub txtIncome_Change() 
   UpdateValues 
End Sub 
'-----------------------------------------------
'//Write data to Google Sheets OR Excel Online
Private Sub cmdSave_Click() 
   Dim wbSrc As BSCloudWorkbook  '//Excel.Workbook
   Dim wsSrc As BSCloudWorksheet  '//Excel.Worksheet
   Dim rngSrc As BSCloudRange  '//Excel.Range
   Dim dataArr(3)  '//Data to upload to Google Sheets
   Set wbSrc = OpenCloudWorkbook 
   Set wsSrc = wbSrc.Sheets("sales") 
   Set rngSrc = wsSrc.Range("A1:D1")  '//Start Row
   '//Save data in controls to data array
   dataArr(0) = cbItems.Text 
   dataArr(1) = Val(txtIncome.Text) 
   dataArr(2) = Val(txtTax.Text) 
   dataArr(3) = Val(txtTotal.Text) 
   Dim res As BSUpdateResponse 
   '//Append data array to Google Sheets, sheet name "sales"
   If Not rngSrc.Append(dataArr, , , , res) Then  '//get res's information
      '//If Not wsSrc.Append(dataArr, res) Then '//Not get res's information
      MsgBoxW "Upload Error.", vbCritical, "Upload Error" 
      Exit Sub 
   End If 
   '//Data upload successful
   MsgBoxW "Data upload successful." & vbNewLine & "The last row is: " & GetLastRow(res.Updates.UpdatedRange), vbInformation, "Upload Ok" 
End Sub 
'-----------------------------------------------
Private Sub UserForm_Terminate() 
   '//Close all connections - Free memory.
   If Not MyCloud Is Nothing Then 
      MyCloud.Workbooks.CloseAll 
      Set MyCloud = Nothing 
   End If 
End Sub 

Type BSUpdateResponse 
   	FileID As String  '//trả về ID của file trên Google Sheets nhận cập nhật
   	TableRange As String  '//Trả về vùng bao dữ liệu quét được. Ví dụ A1:D13
   	Updates As BSUpdateValuesResponse  '//Cấu trúc thông tin vùng cập nhật
End Type 
 Type BSUpdateValuesResponse   
   	FileID As String  '//Giải thíc ở trên
   	UpdatedCells As Long  '//Tổng số ô nhận giá trị
   	UpdatedColumns As Long  '//Tổng số cột nhận giá trị
   	UpdatedData As Variant  '//Dữ liệu hoặc Mảng dữ liệu dã đẩy lên
   	UpdatedRange As String  '//Ðịa chỉ vùng mới thêm. Ví dụ A14:D14
   	UpdatedRows As Long  '//Tổng số dòng được cập nhật.
End Type